home *** CD-ROM | disk | FTP | other *** search
/ PsL Monthly 1993 December / PSL Monthly Shareware CD-ROM (December 1993).iso / prgmming / dos / c / chkflp.exe / CFLOP.ASM < prev    next >
Assembly Source File  |  1991-12-05  |  8KB  |  201 lines
  1. ; File......: FLOPTST.ASM
  2. ; Author....: Joseph LaCour
  3. ; Date......: $Date:   15 Aug 1991 23:07:48  $
  4. ; Revision..: $Revision:   1.2  $
  5. ; Log file..: $Logfile:   E:/nanfor/src/floptst.asv  $
  6. ; 
  7. ; This is an original work by Joseph LaCour and is placed in the
  8. ; public domain.
  9. ;
  10. ;
  11. ;  ACKNOWLEDGEMENTS:
  12. ;
  13. ;          PAOLO RAMOZZI FOR HIS WORK IN DBDCHECK FOR SHOWING HOW TO
  14. ;          USE INT 13H.
  15. ;
  16. ;
  17. ; Modification history:
  18. ; ---------------------
  19. ;
  20. ; $Log:   E:/nanfor/src/floptst.asv  $
  21. ;  
  22. :     Rev 2.0   04 Dec 1991 09:16:00   Kevin Traub
  23. ;  Modified to be a 'c' callable function. Calling convention:
  24. ;        extern unsigned far ft_floptst(int drivenumber);
  25.  
  26. ;  Removed Clipper interface, and removed check for invalid parameters to
  27. ;  reduce overhead. Clipper Program was about 115k, 'c' .exe is now about 4k.
  28. ;  use MS Masm 5.1 or higher to assemble - No arguments, Model already defined
  29. ;  as Large.
  30. ;  Compile accompanying 'c' pgm as large model and link with defaults
  31. ;  eg: masm cflop.asm;
  32. ;      cl /AL /c callclp.c
  33. ;      link callcflp.obj+cflop.obj;
  34. ;
  35. ;  Executable callcflp will set DOS ERRORLEVEL based on condition of specified
  36. ;  floppy. eg. callcflp A    - will test drive A for readiness, if drive is
  37. ;  not ready (Door open or no disk) .exe will set ERRORLEVEL to 1, and will
  38. ;  temporarily (duration of callcflp.exe) intercept DOS critical error handler
  39. ;  so there will be no RETRY,IGNORE,ABORT, FAIL? message.
  40. ;  ERRORLEVELS set as follows:
  41. ;    0 - Drive Loaded and ready to read or write
  42. ;    1 - Drive Door Open or Diskette inserted upside down
  43. ;    2 - Diskette is unformatted
  44. ;    3 - Write protected
  45. ;    4 - Undetermined
  46. ;  Arguments to callcflp.exe are A or B, case insensitive, : not necessary.
  47. ;
  48. ;     Rev 1.2   15 Aug 1991 23:07:48   GLENN
  49. ;  Forest Belt proofread/edited/cleaned up doc
  50. ;  
  51. ;     Rev 1.1   11 May 1991 00:21:42   GLENN
  52. ;  File header changed to conform to Toolkit standard.
  53. ;
  54. ;  $DESCRIPTION$
  55. ;      FT_FLOPTST() returns a numeric code designating the
  56. ;      diskette drive's status.
  57. ;
  58. ;      FT_FLOPTST() is particularly useful in backup and restore programs
  59. ;      that need to test the floppy drive before writing/reading from a
  60. ;      floppy disk.
  61.  
  62.  
  63. .MODEL LARGE
  64.  
  65. _FT_DATASEG  SEGMENT PUBLIC  'DATA'
  66.  
  67. FDRIVE          DB      0
  68. BOOT_SECT       DB      512 DUP (0)
  69.  
  70. _FT_DATASEG  ENDS
  71.  
  72. _NANFOR   SEGMENT 'CODE'
  73.         ASSUME  CS:_NANFOR,DS:_FT_DATASEG,ES:_FT_DATASEG,SS:NOTHING
  74.  
  75. public   _ft_floptst
  76. _ft_floptst      proc    far
  77.  
  78.                 push    bp              ; Entry sequence - save old BP
  79.                 mov     bp,sp           ; Set stack framepointer
  80.  
  81.                 mov     ax,[bp+6]       ; Load Arg2 into AX
  82.  
  83.  
  84.                 push    ax              ; save drive
  85.                 PUSH    AX
  86.                 int     11h             ; get equipment list
  87.                 mov     ah,0            ; clear high byte
  88.                 mov     cl,6            ; set shift count
  89.                 shr     al,cl           ; shift diskette count
  90.                 pop     bx              ; restore drive
  91.                 cmp     bl,al           ; does drive exist?
  92.                 jbe     ParamOk         ; yes, so continue
  93. derror:         jmp     short Ferror    ; Invalid drive
  94.  
  95. ParamOk:
  96.                 POP     AX
  97.                 push    ds              ; Save DS
  98.                 mov     dx,_FT_DATASEG  ; DATA SEGMENT
  99.                 MOV     DS,DX           ; IN DS REGISTER
  100.                 MOV     ES,DX           ; IN ES REGISTER
  101.                 MOV     FDRIVE,AL       ; SAVE DRIVE NUMBER
  102.                 XOR     AX,AX           ; RESET DISKETTE SYSTEM
  103.                 INT     13H             ; CALL BIOS
  104.                 CALL    _FTFLOPT        ; TEST DISKETTE TYPE
  105.                 POP     DS              ; RESTORE DS
  106.                 JMP     SHORT EXIT      ; RETURN
  107.  
  108. FERROR:
  109.                 MOV     AX,-1           ; BAD PARAMETERS
  110.  
  111. EXIT:
  112.                                         ; Leave return value in AX
  113.  
  114.                 pop     bp              ; Restore old framepointer
  115.                 ret     4               ; Exit, and restore 4 bytes of args
  116.  
  117. _ft_floptst      endp
  118.  
  119. ;-----------------------------------------------------------;
  120. ; LOCAL SUBROUTINE - CALL BIOS INT 13 FOR READ SECTOR       ;
  121. ;-----------------------------------------------------------;
  122.  
  123. _FTINT13        PROC    NEAR
  124.                 PUSH    BX              ; SAVE REGS
  125.                 PUSH    ES              ;
  126.                 PUSH    AX              ;
  127.                 INT     13H             ; CALL BIOS (read sector)
  128.                 jnc     ftIntRet        ; Read ok. Exit
  129.                 xor     ax,ax           ; reset diskette system
  130.                 int     13h             ; call BIOS
  131.                 pop     ax              ; restore regs
  132.                 pop     es              ; for retry
  133.                 push    es              ; save regs
  134.                 push    ax              ;
  135.                 int     13h             ; call BIOS (read sector)
  136.                 jnc     ftIntRet        ; Read ok. Exit
  137.                 xor     ax,ax           ; reset diskette system
  138.                 int     13h             ; call BIOS
  139.                 pop     ax              ; restore regs
  140.                 pop     es              ; for retry
  141.                 push    es              ; save regs
  142.                 push    ax              ;
  143.                 int     13h             ; call BIOS (read sector)
  144. ftIntRet:       pop     bx              ; restore regs
  145.                 pop     es              ;
  146.                 pop     bx              ;
  147.                 ret                     ; near return
  148.  
  149. _ftint13        endp
  150.  
  151. ;-----------------------------------------------------------;
  152. ; Local subroutine - check boot sector                      ;
  153. ;-----------------------------------------------------------;
  154.  
  155. _ftflopt        proc    near
  156.  
  157.                 push    di              ; preserve
  158.                 mov     di,OFFSET _FT_DataSeg:boot_sect   ; address of buffer
  159. ftflopred:
  160.                 xor     dx,dx           ; clear DX
  161.                 mov     dl,fdrive       ; drive number in DL
  162.                 mov     cx,0001h        ; track 0, sector 1
  163.                 mov     bx,di           ; buffer addr in ES:BX
  164.                 mov     ax,0201h        ; read one sector
  165.                 call    _ftint13        ; call BIOS
  166.                 jnc     Flop1           ; Read ok. Continue
  167.                 cmp     ah,80h          ; drive not ready ?
  168.                 je      Flop_out        ; Yes.
  169.                 cmp     ah,02h          ; unformatted?
  170.                 je      Flop_for        ; Yes
  171.                 mov     ax,4            ; otherwise, unknown
  172.                 jmp     short Flop_End  ; and exit
  173. Flop1:
  174.                 xor     dx,dx           ; clear DX
  175.                 mov     dl,fdrive       ; drive number in DL
  176.                 mov     cx,0001h        ; track 0, sector 1
  177.                 mov     bx,di           ; buffer addr in ES:BX
  178.                 mov     ax,0301h        ; write one sector
  179.                 call    _ftint13        ; call BIOS
  180.                 jnc     Flop_OK         ; Write ok. Disk s/b AOK
  181.                 cmp     ah,03h          ; Write protected?
  182.                 jne     Flop_OK         ; No disk AOK
  183.                 mov     ax,3
  184.                 jmp     short Flop_End
  185. Flop_out:
  186.                 mov     ax,1
  187.                 jmp     short Flop_End
  188. Flop_for:
  189.                 mov     ax,2
  190.                 jmp     short Flop_End
  191. Flop_OK:
  192.                 xor     ax,ax           ; AX = 0
  193. Flop_End:
  194.                 pop     di              ; restore
  195.                 ret                     ; near return
  196.  
  197. _ftflopt        endp
  198.  
  199. _nanfor         ends
  200.                 end
  201.